/** 
My Day 30 Project for 30daysofcreativity <br/>
by <a href="http://www.local-guru.net/blog">guru</a>
*/

PVector[] particles;
PVector[] vel;
int[] ttl;

PImage img; 

void setup() {
  size(600,300);

  particles = new PVector[40];
  vel = new PVector[40];
  ttl = new int[40];
  for( int i=0; i<particles.length/2; i++) {
    particles[i] = new PVector(0,0);
    vel[i] = new PVector(random(-1,1),random(-5,-1));
    ttl[i] = int(random(50,100));
  }
  for( int i=particles.length/2; i < particles.length; i++) {
    particles[i] = new PVector(0,0);
    vel[i] = new PVector(0,0);
    ttl[i] = int(random(0,50));
  }
  img = makeTexture( 5 );
  textFont( loadFont( "Arial-Black-64.vlw"), 64);
}

void draw() {
  background(0);
  stroke(255);
  strokeWeight(2);
  text( "DAY 30", 190,300 );
  for( int i=0; i<particles.length; i++) {

    blend( img, 0,0, img.width, img.height, int(particles[i].x)+150, int(particles[i].y)+280, img.width, img.height, ADD );
    blend( img, 0,0, img.width, img.height, int(particles[i].x)+450, int(particles[i].y)+280, img.width, img.height, ADD );
    particles[i].add( vel[i] );
    ttl[i]--;
    if (ttl[i] < 0) {
      particles[i] = new PVector(0,0);
      vel[i] = new PVector(random(-1,1),random(-5,-1));
      ttl[i] = int(random(50,100));
    }
  }
}

PGraphics makeTexture( int r ) {
  PGraphics res = createGraphics( r * 6, r * 6, P2D);
  res.beginDraw();
  res.loadPixels();
    for ( int x = 0; x < res.width; x++) {   
      for( int y = 0; y < res.height; y++ ) {
        float d = min( 512, 50*  sq( r / sqrt( sq( x - 3 * r) + sq( y - 3 * r))));
        //if ( d < 10 ) d = 0;
        res.pixels[y * res.width + x] = color( min(255,d), min(255, d*0.8), d* 0.5 );
      }
    }
  res.updatePixels();
  res.endDraw();
  
  return res;  
}