/**
a small demo how linedetection with houg-transformation 
works by <a href="http://www.local-guru.net/blog/guru>guru</a>
*/
void setup() {
  size(900,300);
}

void draw() {
  background(0);
  // draw input image
  stroke( 255 );
  noFill();
  rect(120,20, 50, 60);
  line(20,20, 260, 280);
  
  
  // get hough transform
  for( int y=0; y<300; y++) {
    for( int x = 0; x<300; x++) {
      if ( get( x, y ) == color( 255 )) {
        // map x and y to the range of -1 to 1
        float xp = map(x,0,300,-1,1);
        float yp = map(y,0,300,-1,1);
        
        // for every angle get the radius and mark
        // the point in the parameter space
        for( float roh = 0; roh < PI; roh+=PI/300) {
          float p = xp * cos(roh) + yp * sin(roh);
          int hx = int(300 + map( roh, 0, PI, 0, 300));
          int hy = int(map( p, -1, 1, 0, 300));
          
          color c = get(hx,hy);
           
          set( hx,hy, color( brightness(c) + 4));     
        }
      }
    }
  }
  
  // reconstruct
  for( int y = 0; y < 300; y++) {
    for( int x = 0; x < 300; x++) {
      
      //get the brightest points in parameter space
      color c = get( 300 + x, y);
      if (brightness(c) > 120) {
         set(300+x,y,color(0,255,0));
         float roh = map( x - 300, 0, 300, 0, PI );
         float r = map( y, 0, 300, -1, 1 );
         // calculate the startpoint
         float xx = cos( roh ) * r;
         float yy = -sin( roh ) * r;
      
         stroke(255,255,0);
         if (sin(roh)<0) {
           // calculate the angle
           float k = -cos(roh)/sin(roh);
           // draw the line
           line(int(600 + map(xx -0.5, -1, 1, 0, 300)), 
                int(map(yy -k/2, -1, 1, 0, 300)), 
                int(600 + map(xx+ 0.5, -1, 1, 0, 300)),
                int(map(yy+ k/2, -1, 1, 0, 300)));                
        }
      }      
    }
  }
}