/**
  Abstract Art Generator 4 - by <a href="http://www.local-guru.net/blog">Guru</a><br/>
  press any key to generate a new image
*/
Blob[] blobs;

void setup() {
  size(300,300);
  blobs = new Blob[10];
  colorMode( HSB );
  for( int i =0; i <10; i++) {
    blobs[i] = new Blob( new PVector( random(10,290), random(10,290)), color(random(255),255,255,random(50,200)));
  }
  noLoop();
}

void draw() {
  background(255);
  for( int i=0; i<10; i++) {
    blobs[i].draw();
  }
}

void keyPressed() {
  for( int i =0; i <10; i++) {
    blobs[i] = new Blob( new PVector( random(10,250), random(10,250)), color(random(255),255,255,random(50,200)));
  }
  redraw();
}
public class Blob {
  PVector center;
  color c;
  PVector[] points = new PVector[13];

  public Blob( PVector center, color c ) {
    for ( int i =0; i < 10; i++) {
      float r = random(30, 100 );
      points[i] = new PVector( cos( i*TWO_PI/10 ) * r, sin( i*TWO_PI/10) * r );
    }
    points[10] = points[0];
    points[11] = points[1];
    points[12] = points[2];
    this.center = center;
    this.c = c;
  }

  void draw() {
    fill(c);
    noStroke();
    beginShape();
    for ( int i =0; i < 13; i++) {
      curveVertex( points[i].x + center.x, points[i].y + center.y);
    }  
    endShape(CLOSE);
  }
}