/**
3D mousefollowing wyes with parametric texture by <a href="http://www.local-guru.net/blog">Guru</a>
*/

PImage world;

void setup() {
  size(400, 400, P3D);
  frameRate( 25 );
  //smooth();
  PGraphics g = createGraphics(400, 200, JAVA2D);
  g.beginDraw();
  g.background(255);
  g.fill(0, 0, 255);
  g.noStroke();
  g.rect(0, 160, 400, 40);
  g.strokeWeight(4);
  for ( int i =0; i<g.width;i++) {
    g.stroke(0, 0, 128+random(128));
    g.line( i, g.height, i, g.height-random(30));
  }
  g.noStroke();
  g.fill(0);
  g.rect(0, 185, 400, 15);
  g.endDraw();

  world = createImage( g.width, g.height, RGB);
  world.copy( g, 0, 0, g.width, g.height, 0, 0, g.width, g.height);
}

float a = 0;

void draw() {
  background( 0 );
  lights();
  noStroke();
  fill(128);
  translate( width/2, height/2);

  PVector look = new PVector( mouseX-width/2, mouseY-height/2, 200);

  drawEye( new PVector( 80,0,-40), look );
  drawEye( new PVector( -80,0,-40), look );
}

void drawEye( PVector pos, PVector l ) {
  PVector look = new PVector( l.x, l.y, l.z );
  PVector o = new PVector( -80,0,-40);
  look.sub( pos );
  look.normalize();
  float roh = acos( look.y );
  float phi = atan( look.x / look.z );

  pushMatrix();
  translate( pos.x,pos.y,pos.z );
  rotateY( phi );
  rotateX( roh );
  makeSphere( 80, 5, world );
  popMatrix();

}


public void makeSphere( int R, int step, PImage tex ) {
  beginShape(TRIANGLE_STRIP);
  texture( tex );
  for ( int i = 0; i < 90; i+=step ) {
    float sini = sin( radians( i ));
    float cosi = cos( radians( i ));
    float sinip = sin( radians( i + step ));
    float cosip = cos( radians( i + step ));

    for ( int j = 0; j < 360; j+=step ) {
      float sinj = sin( radians( j ));
      float cosj = cos( radians( j ));
      float sinjp = sin( radians( j + step ));
      float cosjp = cos( radians( j + step ));

      // Upper hemisphere
      vertex( R * cosj * sini, R * -cosi, R * sinj * sini, // x, y, z
      tex.width-j * tex.width / 360, i * tex.height / 180 // u, v
      );
     
     

      vertex( R * cosjp * sini, R * -cosi, R * sinjp * sini, 
      tex.width-(j + step ) * tex.width / 360, i * tex.height / 180
        );
      
      vertex( R * cosj * sinip, R * -cosip, R * sinj * sinip, 
      tex.width-j * tex.width / 360, (i + step ) * tex.height / 180
        );
        
      vertex( R * cosjp * sinip, R * -cosip, R * sinjp * sinip, 
      tex.width-(j + step ) * tex.width / 360, (i + step ) * tex.height / 180
        );        
      // Lower hemisphere        
      vertex( R * cosj * sini, R * cosi, R * sinj * sini, 
      tex.width-j * tex.width / 360, tex.height - i * tex.height / 180
        );

      vertex( R * cosjp * sini, R * cosi, R * sinjp * sini, 
      tex.width-(j + step ) * tex.width / 360, tex.height - i * tex.height / 180
        );

      vertex( R * cosj * sinip, R * cosip, R * sinj * sinip, 
      tex.width-j * tex.width / 360, tex.height - (i+step) * tex.height / 180
        );

      vertex( R * cosjp * sinip, R * cosip, R * sinjp * sinip, 
      tex.width-(j+step) * tex.width / 360, tex.height - (i+step) * tex.height / 180
        );

    }
  }
  endShape();
}