GuruBlog

I created another set of images to hang on my livingroom wall. Here is an example of the generated images and the code of the sketch I used

The code creates a petal with no stroke and an pastel fill color and then redraws the shape 3 times without a fill color.

Each flower draws 5 petals and I draw 6 flowers per Image at random y positions

void setup() {
  size(694, 820);
  noLoop();
  colorMode(HSB);
}

void draw() {
  background(255);

  for( int k = 0; k < 6; k++) {
    pushMatrix();
  translate( width/2 - 250 + k*100, height/2 + random(-100,200));
  scale( .5);
  line(0,0,random(-50,50), height*2 );
  rotate( random( -PI, PI ));
  float c = random(255);

  for ( int j=0; j<5; j++) {
    pushMatrix();
    rotate(j * TWO_PI/5);
    noStroke();
    fill( c, 50, 255);
    petal();
    stroke(128);
    noFill();

    for ( int i=0; i<3; i++) {
      petal();
    }
    popMatrix();
  }
  popMatrix();
  }
}

void mousePressed() {
  saveFrame("####.png");
  redraw();
}

void petal() {

  beginShape();
  curveVertex(0, 0 );
  curveVertex(0 + random(-10, 10), 0+ random(-10, 10) );
  curveVertex(-50+ random(-10, 10), -100+ random(-10, 10) );
  curveVertex( 0+ random(-10, 10), -100+ random(-10, 10));
  curveVertex(50+ random(-10, 10), -100+ random(-10, 10));
  curveVertex(0+ random(-10, 10), 0+ random(-10, 10));
  curveVertex(0, 0);
  endShape();
}