GuruBlog

i have used processing to access map materials from geoserver. but i have noticed that the earth is not flat and that processing is making 3d animations really easy :-)

so i have coded a rotating sphere and project the GIS data from geoserver on the surface

flat map from my last sketch

spherical map from the new sketch

The code accesses the geoserver only in the setup method yet. If the data that is displayed varies over the time, update it in the draw method.

PImage world;

void setup() {
  size(400,400, P3D);
  frameRate( 25 );
  //smooth();  
  world = getWMS( "http://localhost:8080/geoserver/wms", "topp:TM_WORLD_BORDERS-0", -180, -90, 180, 90, 1600, 800 );
}

float a = 0;

void draw() {
  background( 0 );
  lights();
  noStroke();
  fill(128);
  translate( width/2, height/2);

  pushMatrix();
  rotateX( radians(-30));
  rotateY( a );
  a+= 0.01;   
  makeSphere( 150, 10, world );

  popMatrix();
}


PImage getWMS( String url, String layer, float minlon, float minlat, float maxlon, float maxlat, int width, int height ) {
  PImage res = loadImage( url + "?request=GetMap&layers=" + layer +"&bbox="+minlon+","+minlat+","+maxlon+","+maxlat+"&format=image/png&width="+width+"&height="+height, "png");
  return res;
} 


public void makeSphere( int R, int step, PImage tex ) {
  beginShape(TRIANGLE_STRIP);
  texture( tex );
  for( int i = 0; i < 90; i+=step ) {
    float sini = sin( radians( i ));
    float cosi = cos( radians( i ));
    float sinip = sin( radians( i + step ));
    float cosip = cos( radians( i + step ));

    for( int j = 0; j < 360; j+=step ) {
      float sinj = sin( radians( j ));
      float cosj = cos( radians( j ));
      float sinjp = sin( radians( j + step ));
      float cosjp = cos( radians( j + step ));

      // Upper hemisphere
      vertex( R * cosj * sini, R * -cosi, R * sinj * sini, // x, y, z
              tex.width-j * tex.width / 360, i * tex.height / 180 // u, v
              );

      vertex( R * cosjp * sini, R * -cosi, R * sinjp * sini,
              tex.width-(j + step ) * tex.width / 360, i * tex.height / 180
      );

      vertex( R * cosj * sinip, R * -cosip, R * sinj * sinip, 
              tex.width-j * tex.width / 360, (i + step ) * tex.height / 180
              );

      vertex( R * cosjp * sinip, R * -cosip, R * sinjp * sinip, 
              tex.width-(j + step ) * tex.width / 360, (i + step ) * tex.height / 180
              );        

      // Lower hemisphere        
      vertex( R * cosj * sini, R * cosi, R * sinj * sini,
              tex.width-j * tex.width / 360, tex.height - i * tex.height / 180
              );

      vertex( R * cosjp * sini, R * cosi, R * sinjp * sini,
              tex.width-(j + step ) * tex.width / 360, tex.height - i * tex.height / 180
              );

      vertex( R * cosj * sinip, R * cosip, R * sinj * sinip,
              tex.width-j * tex.width / 360, tex.height - (i+step) * tex.height / 180
              );

      vertex( R * cosjp * sinip, R * cosip, R * sinjp * sinip,
              tex.width-(j+step) * tex.width / 360, tex.height - (i+step) * tex.height / 180
              );
    }
  }
  endShape();
}